GEE师徒系统全整理

2020-02-20 11:01:26  阅读 1023 次 评论 1 条

=========================================
标准脚本
[@main]
<我想拜师/@master>\
<我想出师/@unmaster>\ \
<离开/@exit>

[@master]
想拜师呀,你要拜的师父来了没有?\
与你师父面对面站好,开始拜师。\ \
<准备好了/@agree>\
<我知道了/@exit>\ \
<返回/@main>

[@agree]
;检查是不是已经是别人的师父
#if
   checkismaster

#act
   break
#say
没事别来这玩!!!\ \
<返回/@main>

;检查是不是已经拜师了
#if
   checkmaster
#act
   break
#say
你都都已经拜了别人为师,怎么还拜师!!! \ \
<返回/@main>

;检查对面的人物是不是别人的徒弟
#if
  checkposemaster
#say
你找了个什么人做师父,怎么现在还是别人的徒弟?\ \
<返回/@main>
#act
  break

;检查二个有没站好位置
#if
   checkposedir
#elsesay
你们二个面对面站好呀,不要乱动。\ \
<返回/@main>
#elseact
  break

#if
  checklevel 40
#say
你都40多级了还要找师父?\ \
<返回/@main>
#act
  break

;检查对方等级
#if
  checkposelevel > 50
#elsesay
你找个什么师父呀,等级这么低?\ \
<返回/@main>
#elseact
  break
#act
   master

[@StartGetMaster]
拜师仪式正式开始。\ \
你是否确认拜师?\ \
<确认/@RequestMaster>

[@StartMaster]
拜师仪式正式开始。\ \
对方已经向你提出拜师请求。\ \


[@RequestMaster]

;检查所需物品
#if
   checkitemw 力量戒指 1
#elsesay
你都没信物,怎么拜呀!!!\ \
<返回/@main>
#elseact
   break

#if
#act
   takew 力量戒指 1
   master requestmaster

[@WateMaster]
你已向对方请求拜师,请耐心等待对方的答复。

[@RevMaster]
对方想拜你为师,你是否想收此人为徒? \ \
<同意/@ResposeMaster> \
<不同意/@ResposeMasterFail>

[@ResposeMaster]
#if
#act
  master responsemaster ok

[@ResposeMasterFail]
#if
#act
  master responsemaster fail
[@EndMaster]
你们二个已经是师徒关系了。\ \
<关闭/@exit>
[@EndMasterFail]
拜师失败!\ \
<关闭/@exit>
[@MasterDirErr]
对方没站好位置

[@MasterCheckDir]
请站好位置\

[@HumanTypeErr]
此人不可以做你的师父。

;开始
[@unmaster]
#if
   havemaster
#act
   unmaster
#elsesay
你都没师父,跑来做什么??\ \
<返回/@main>

[@UnMasterCheckDir]
按正常出师步骤,必须二个人对面对站好位置,\
如果人来不了你只能选择强行出师了。\ \
<我要强行出师/@fUnMaster>\
<返回/@main>

;对面位置不是人物时显示的信息
[@UnMasterTypeErr]
你对面站了个什么东西,怎么不太象人来的。\ \
<返回/@main>
[@UnIsMaster]
必须由徒弟发出请求!!!\ \
<返回/@main>
[@UnMasterError]
不要来捣乱!!!\ \
<返回/@main>

;开始程序后,双方显示的信息
[@StartUnMaster]
出师仪式现在开始!!!\ \
是否确定真的要脱离师徒关系?\ \
<确定/@RequestUnMaster>
[@WateUnMaster]
出师仪式现在开始!!!\ \

;发出请求
[@RequestUnMaster]
#if
  havemaster
#act
  unmaster requestunmaster

;回应请求
[@ResposeUnMaster]
#if
  havemaster
#act
  unmaster responseunmaster

;请求后显示的信息
[@WateUnMaster]
你已向对方发出请求,请耐心等待对方的答复。

;请求后对方显示的信息
[@RevUnMaster]
对方向你请求,你是否答应? \ \
<我愿意/@RequestUnMaster>
<返回/@main>
[@ExeMasterFail]
你都没师父,跑来做什么? \ \
[返回/@main]

;强行
[@fUnMaster]
#if
  checkitem 金条 1
  havemaster
#act
  take 金条 1
  unmaster requestunmaster force
#elsesay
要收一根金条的手续费,你没有金条,\
<确定/@exit>
;完成后的提示信息
[@UnMasterEnd]
呵呵,你已经脱离师徒关系了
=========================================
师徒信息保存在:Envir\MasterNo 目录 不知道里面文件内容不要乱搞就行
=========================================
多徒弟系统(引擎上设置徒弟数量) 设置位置 M2 选项 功能设置 师徒系统 可设置出师等级,师父所得.收徒数量
========================================
多徒弟系统师傅身上不在显示是XXXX的师傅!
修改 string.ini 中下面的配置(不改也可以,但不会显示徒弟是第几个)
NoMasterName=%s的%n徒弟
MasterOnlineSelfMsg=你的%n徒弟%s当前位于%m(%x:%y)。
MasterNotOnlineMsg=你的%n徒弟%s现不在线!!!
MasterListOnlineMasterMsg=你的%n徒弟%s在:%m(%x:%y)上线了!!!。
MasterListLongOutMasterOnlineMsg=你的%n徒弟%s在:%m(%x:%y)下线了!!!。
YourMasterListUnMasterOKMsg=你的%n徒弟%d已经圆满出师了!!!
=========================================
设置显示名称格式
配置文件:String.ini
以下为相关配置内容:
CastleGuildName=%guildname[%castlename(%rankname)]
NoCastleGuildName=%guildname(%rankname)
WarrReNewName=%chrname\*<圣>*
WizardReNewName=%chrname\*<神>*
TaosReNewName=%chrname\*<尊>*
ManDearName=%s的老公
WoManDearName=%s的老婆
MasterName=%s的师父
NoMasterName=%s的徒弟
HumanShowName=%chrname\%guildname\%dearname\%mastername

CastleGuildName        沙城成员显示行会格式
NoCastleGuildName  普通已加入行会人员显示行会格式
%guildname  行会名称
%castlename 城堡名称
%rankname   职位名称
WarrReNewName  武士转生后名称显示
WizardReNewName  法师转生后名称显示
TaosReNewName  道士转生后名称显示
%chrname 人物名称
ManDearName 结婚后男的显示名称
WoManDearName 结婚后女的显示名称
MasterName 师父显示名称
NoMasterName 徒弟显示名称
HumanShowName 显示完整名称格式

游戏中显示出来的名称是根据以上格式组合出来的,大家可以根据自己的要求,自行调行组合及格式。
==========================
相关变量
<$STNAME>    师徒名称变量
==========================
攻击模式设置
SetHumAttackMode 攻击模式(0-7) 时间(秒) 地图号(*为任何地图)
0-全体攻击(主动攻击) 1-和平攻击(不PK) 2-夫妻攻击 3-师徒攻击 4-编组攻击 5-行会攻击
;6-红名攻击(不主动攻击,受攻击后反击)

SetHumAttackMode 3 18000 *
==========================
相关命令(可在引擎修改)  修改位置 M2 选项 游戏命令 玩家命令
@Master    师徒查询位置
@MasterRecall    师徒传送   
@AllowMasterRecall    允许师徒传送
==========================
自动出师触发 QFunction-0.txt
[@UnMasterEnd]
#IF
#ACT
SENDMSG 6 提示:师傅触发!
[@UnMasterEnd1]
#IF
#ACT
SENDMSG 6 提示:徒弟触发!

强制(脱离师徒)出师:
强制脱离要上下线才能触发的.
@ForceUnMasterEnd 师傅触发
@ForceUnMasterEnd1 徒弟触发
=========================================
功能:
    用来检查人物的师傅或者徒弟是否在线上
命令格式:
    CHECKMASTERONLINE 徒弟序号(为空表示大徒弟)
#if
   CHECKMASTERONLINE
#say
   你的师傅(或徒弟)在线
#elsesay
   你的师傅(或徒弟)不在线
=========================================
功能:
    清除当前人物的拜师信息
格式:
    DELMASTER 徒弟序号(为空表示大徒弟、师傅清除指定徒弟使用,徒弟清除师傅以下是示例脚本)
[@Main]
#IF
#ACT
  DELMASTER
#SAY
你已经和你师傅脱离关系了
;==========================================
功能:
    检测对面是否为自己的徒弟
格式:
  CHECKPOSEISPRENTICE
[@Main]
#if
    CHECKPOSEISPRENTICE
#say
   对面的是你徒弟哦!
#elsesay
   对面的不是你徒弟!
;==========================================
功能:
    用来检测自己是否是徒弟
命令格式:
    CHECKISPRENTICE
[@Main]
#if
   CHECKISPRENTICE
#say
   你是徒弟
#elsesay
   你不是徒弟
;==========================================
功能:
    检查自己是不是别人的徒弟
命令格式:
    POSEHAVEMASTER
[@Main]
#if
    POSEHAVEMASTER
#say
   你是别人的徒弟
#elsesay
   你不是别人的徒弟
==========================
获取徒弟列表
GetMasterList 变量名
[@GetMasterList]
#if
#act
GetMasterList S1
#SAY
你当前的徒弟有<$STR(S1)>
==========================
获取徒弟数量
GetMasterCount 变量名
[@GetMasterCount]
#if
#act
GetMasterCount P1
#SAY
你当前的徒弟有<$STR(P1)>人
==========================
检测对面的有没有徒弟
功能:
    POSEHAVEPRENTICE
命令格式:
    POSEHAVEPRENTICE
[@main]
#if
    POSEHAVEPRENTICE
#say
   对面有徒弟
#elsesay
   对面没有徒弟
==========================
相关地图参数
NOMasterRECALL     禁止师徒传送
==========================
查人物所在地图是否允许使用记忆 夫妻 师徒传
[@main]
#IF
CheckRecall 人物名字
#SAY
当前地图不允许被传送.

手机扫描二维码访问

本文地址:https://www.uc845.com/post/559.html
版权声明:本文为原创文章,版权归 游戏开发者 所有,欢迎分享本文,转载请保留出处!
  • 盟重
  • 您需要 登录账户 后才能发表评论

    发表评论


    表情

    评论列表

    1. 学习传奇教程
      学习传奇教程  @回复
      楼主收徒吗?我想拜你为师,学习写传奇脚本,写传奇版本,写传奇引擎。 face_19